Subversion Repositories pentevo

Rev

Rev 627 | Rev 666 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.  
  2. ;LAST UPDATE: 02.02.2014 savelij
  3.  
  4. ;КОПИРОВАНИЕ 256 БАЙТ
  5. COPY_BLOCK      REPT 128                        ;КОПИРОВАНИЕ БЛОКА 256 БАЙТ
  6.                 LDI
  7.                 ENDM
  8. COPYHBLOCK      REPT 126
  9.                 LDI
  10.                 ENDM
  11.                 JR COPY_BLOCK1
  12.                
  13.                 DW 0XFFFF                       ;ДЛЯ ВЕКТОРА ПРЕРЫВАНИЙ IM2 I=9
  14.  
  15. COPY_BLOCK1     LDI
  16.                 LDI
  17.                 RET
  18.  
  19. WOUT1F          EQU 0
  20. WOUT3F          EQU WOUT1F+1
  21. WOUT5F          EQU WOUT3F+1
  22. WOUT7F          EQU WOUT5F+1
  23. WOUTFF          EQU WOUT7F+1
  24. WOUTI           EQU WOUTFF+1
  25. WIN1F           EQU WOUTI+1
  26. WIN3F           EQU WIN1F+1
  27. WIN5F           EQU WIN3F+1
  28. WIN7F           EQU WIN5F+1
  29. WINFF           EQU WIN7F+1
  30. WINI            EQU WINFF+1
  31. WOUTCD          EQU WINI+1
  32. WINHC           EQU WOUTCD+1
  33. WWR_RD_SECT     EQU WINHC+1
  34.  
  35. WOUTCA          EQU WWR_RD_SECT+1
  36. WWRITE_SEC_     EQU WOUTCA+1
  37. WREAD_SEC_      EQU WWRITE_SEC_+1
  38. WINI_RET        EQU WREAD_SEC_+1
  39.  
  40. W_DATA          DW W_OUT1F                      ;00
  41.                 DW W_OUT3F                      ;01
  42.                 DW W_OUT5F                      ;02
  43.                 DW W_OUT7F                      ;03
  44.                 DW W_OUTFF                      ;04
  45.                 DW W_OUTI                       ;05
  46.                 DW W_IN1F                       ;06
  47.                 DW W_IN3F                       ;07
  48.                 DW W_IN5F                       ;08
  49.                 DW W_IN7F                       ;09
  50.                 DW W_INFF                       ;0A
  51.                 DW W_INI                        ;0B
  52.                 DW W_OUTCD                      ;0C
  53.                 DW W_INHC                       ;0D
  54.                 DW W_WR_RD_SECT                 ;0E
  55. EW_DATA
  56.                 DW W_OUTCA                      ;0F
  57.                 DW WRITE_SEC_                   ;10
  58.                 DW READ_SEC_                    ;11
  59.                 DW W_INI                        ;12
  60.  
  61. TEXT4VIRTDRV    DB 0X16,ZASTV_Y+2,0
  62. TXT4VIRTDRV     DC "Virtual Drive: "
  63. ETXT4VIRTDRV
  64.  
  65. RST08_WORK      EX (SP),HL
  66.                 PUSH AF
  67.                 PUSH BC
  68.                 LD A,I
  69.                 JP PE,RST08_WORK1
  70.                 LD A,I
  71. RST08_WORK1     DI
  72.                 PUSH AF
  73.                 LD BC,RD_1WINA0
  74.                 IN A,(C)
  75.                 PUSH AF
  76.                 AND 0X3E
  77.                 LD BC,WIN_A0
  78.                 OUT (C),A
  79.                 LD B,HIGH (WIN_P0)
  80.                 LD A,PAGE_EVODOS
  81.                 OUT (C),A
  82.                 IN A,(PEVO_CONF)
  83.                 LD (WR_BF),A
  84.                 OR 1
  85.                 OUT (PEVO_CONF),A
  86.                 POP AF
  87.                 LD (TEK_ROMPAGE),A
  88.                 LD A,(HL)
  89.                 LD (DOS_STEK),SP
  90.                 LD SP,DOS_STEK
  91.                 PUSH HL                         ;ПОЛОЖИЛИ HL=АДРЕС ВОЗВРАТА
  92.                 PUSH DE
  93.                 LD HL,(DOS_STEK)
  94.                 LD DE,REG_IF
  95.                 REPT 8
  96.                 LDI
  97.                 ENDM
  98.                 LD HL,EXIT_RST08
  99.                 PUSH HL                         ;ПОЛОЖИЛИ АДРЕС ЗАВЕРШЕНИЯ
  100.                 LD HL,W_DATA
  101.                 ADD A,A
  102.                 ADD A,L        
  103.                 LD L,A
  104.                 LD A,(HL)
  105.                 INC L
  106.                 LD H,(HL)
  107.                 LD L,A
  108.                 JP (HL)
  109.  
  110. EXIT_RST08      LD HL,REG_IF
  111.                 LD DE,(DOS_STEK)
  112.                 REPT 8
  113.                 LDI
  114.                 ENDM
  115.                 POP DE
  116.                 POP HL
  117.                 LD SP,(DOS_STEK)
  118.                 LD A,(HL)
  119.                 INC HL
  120.                 CP LOW ((EW_DATA-W_DATA)/2)
  121.                 JR C,EXIT_RST082
  122.                 LD HL,FOR_RET
  123. EXIT_RST082     PUSH HL
  124.                 IN A,(RW_PORT0)
  125.                 LD H,A
  126.                 AND 3
  127.                 LD L,A
  128.                 LD A,(MASK_DRV)
  129.                 LD B,A
  130.                 LD A,H
  131.                 AND B
  132.                 CP B
  133.                 JR Z,EXIT_RST085
  134.                 LD A,(WR_FF)
  135.                 AND 3
  136.                 CP L
  137. EXIT_RST085     LD A,(WR_BF)
  138.                 LD BC,WIN_A0+0X100
  139.                 LD HL,DOS_NOEMUL
  140.                 JR NZ,EXIT_RST083
  141.                 INC HL
  142. EXIT_RST083     CALL WRPORT_RET
  143.                 POP HL
  144.                 OUT (PEVO_CONF),A
  145.                 POP AF
  146.                 JP PO,EXIT_RST084
  147.                 EI
  148. EXIT_RST084     LD I,A
  149.                 POP BC
  150.                 POP AF
  151.                 EX (SP),HL
  152.                 RET
  153.  
  154. ;ЗАПИСЬ "A" В ПОРТ 0X1F
  155. W_OUT1F         LD A,(REG_A)
  156.                 LD (WR_1F),A
  157.                 CP 0X10                         ;00-0F КОМАНДА ВОССТАНОВЛЕНИЯ
  158.                 JR NC,W_OUT1F10
  159.                 XOR A
  160.                 OUT (RW_PORT1),A;OUT (0X3F),A
  161.                 JR INFF_BIT6
  162.  
  163. W_OUT1F10       CP 0X20                         ;10-1F КОМАНДА ПОИСКА
  164.                 JR NC,W_OUT1F20
  165.                 IN A,(RW_PORT3)         ;IN A,(0X7F)
  166.                 OUT (RW_PORT1),A        ;OUT (0X3F),A
  167.                 CALL DISK_NONE
  168.                 LD A,0X80
  169.                 JR NZ,INFF_BIT61
  170. INFF_BIT6       XOR A
  171. INFF_BIT61      LD (RD_1F),A
  172.                 LD A,0XBF
  173.                 LD (RD_FF),A
  174.                 RET
  175.  
  176. DISKNONE1       CALL RET_PAGE_STD
  177.                 LD A,0X80
  178.                 JR INFF_BIT61
  179.  
  180. W_OUT1F20       CP 0X40                         ;20-3F КОМАНДА ШАГ В ПРЕДЫДУЩЕМ НАПРАВЛЕНИИ
  181.                 JR NC,W_OUT1F40
  182.                 IN A,(RW_PORT1)         ;IN A,(0X3F)
  183. NAPRAVL         NOP
  184.                 OUT (RW_PORT1),A        ;OUT (0X3F),A
  185.                 JR INFF_BIT6
  186.  
  187. W_OUT1F40       CP 0X60                         ;40-5F КОМАНДА ШАГ ВПЕРЕД
  188.                 JR NC,W_OUT1F60
  189.                 IN A,(RW_PORT1)         ;IN A,(0X3F)
  190.                 INC A
  191.                 OUT (RW_PORT1),A        ;OUT (0X3F),A
  192.                 LD A,0X3C
  193.                 LD (NAPRAVL),A
  194.                 JR INFF_BIT6
  195.  
  196. W_OUT1F60       CP 0X80                         ;60-7F КОМАНДА ШАГ НАЗАД
  197.                 JR NC,W_OUT1F80
  198.                 IN A,(RW_PORT1)         ;IN A,(0X3F)
  199.                 DEC A
  200.                 OUT (RW_PORT1),A        ;OUT (0X3F),A
  201.                 LD A,0X3D
  202.                 LD (NAPRAVL),A
  203.                 JR INFF_BIT6
  204.  
  205. W_OUT1F80       CP 0XA0                         ;80-9F КОМАНДА ЧТЕНИЕ СЕКТОРА
  206.                 JR NC,W_OUT1FA0
  207.                 JR INFF_BIT6
  208.  
  209. W_OUT1FA0       CP 0XC0                         ;A0-BF КОМАНДА ЗАПИСЬ СЕКТОРА
  210.                 JR NC,W_OUT1FD0
  211.                 JR INFF_BIT6
  212.  
  213. INFF_BIT7       XOR A
  214.                 LD (RD_1F),A
  215.                 LD A,0X7F
  216.                 LD (RD_FF),A
  217.                 RET
  218.  
  219. W_OUT1FD0       CP 0XD0                         ;C0-CF ЧТЕНИЕ АДРЕСА
  220.                 JR NC,W_OUT1FE0
  221.                 JR INFF_BIT6
  222.  
  223. W_OUT1FE0       CP 0XE0                         ;D0-DF ПРИНУДИТЕЛЬНОЕ ПРЕРЫВАНИЕ
  224.                 JR NC,W_OUT1FF0
  225.                 LD A,0XBF
  226.                 LD (RD_FF),A
  227.                 RET
  228.  
  229. W_OUT1FF0       CP 0XF0                         ;E0-EF ЧТЕНИЕ ДОРОЖКИ
  230.                 JR C,INFF_BIT6
  231.                 JR INFF_BIT6
  232.  
  233. ;ЗАПИСЬ "A" В ПОРТ 0X3F
  234. W_OUT3F         LD A,(REG_A)
  235.                 OUT (RW_PORT1),A
  236.                 OUT (0X3F),A
  237.                 RET
  238.        
  239. ;ЗАПИСЬ "A" В ПОРТ 0X5F
  240. W_OUT5F         LD A,(REG_A)
  241.                 OUT (RW_PORT2),A
  242.                 OUT (0X5F),A
  243.                 RET
  244.        
  245. ;ЗАПИСЬ "A" В ПОРТ 0X7F
  246. W_OUT7F         LD A,(REG_A)
  247.                 OUT (RW_PORT3),A
  248.                 OUT (0X7F),A
  249.                 RET
  250.  
  251. ;ЗАПИСЬ "A" В ПОРТ 0XFF
  252. W_OUTFF         LD A,(REG_A)
  253.                 OUT (0XFF),A
  254.                 LD (WR_FF),A
  255.                 AND 3
  256.                 INC A
  257.                 LD B,A
  258.                 LD A,%00001000
  259.                 RLCA
  260.                 DJNZ $-1
  261.                 LD (MASK_DRV),A
  262.                 RET
  263.  
  264. ;ЗАПИСЬ "A" В ПОРТ (C)
  265. W_OUTCA         LD A,(REG_A)
  266. W_OUTCA1        LD D,A
  267.                 LD A,(REG_C)
  268. ;ОПРЕДЕЛЕНИЕ В КАКОЙ ПОРТ ЗАПИСЬ       
  269.                 CP 0X1F
  270.                 JP Z,W_OUT1F
  271.                 CP 0X3F
  272.                 JR Z,W_OUT3F
  273.                 CP 0X5F
  274.                 JR Z,W_OUT5F
  275.                 CP 0X7F
  276.                 JR Z,W_OUT7F
  277.                 CP 0XFF
  278.                 JR Z,W_OUTFF
  279.                 LD BC,(REG_C)                   ;ЕСЛИ ПОРТ НЕ TR-DOS
  280.                 OUT (C),D
  281.                 RET
  282.  
  283. ;ЗАПИСЬ "D" В ПОРТ (C)
  284. W_OUTCD         LD A,(IREG_D)
  285.                 JR W_OUTCA1
  286.        
  287. ;ПЕРЕДАЧА БАЙТА, КОМАНДА OUTI
  288. W_OUTI          LD HL,(BUFF_SECT)
  289.                 EXX
  290.                 LD A,(HL)
  291.                 INC HL
  292.                 EXX
  293.                 LD (HL),A
  294.                 INC HL
  295.                 LD (BUFF_SECT),HL
  296.                 RET
  297.  
  298. ;ЧТЕНИЕ ПОРТА 0X1F     
  299. W_IN1F          LD A,(WR_1F)
  300.                 AND 0XF0
  301.                 CP 0X10
  302.                 JR C,W_IN1F1
  303.                 CP 0X20
  304.                 JR C,W_IN1F3
  305.                 CP 0XD0
  306.                 JR Z,W_IN1F1
  307.                 XOR A
  308.                 JR W_IN1F2
  309.  
  310. W_IN1F3         LD A,(INDEX)
  311.                 XOR %00000100
  312.                 JR W_IN1F4
  313.  
  314. W_IN1F1         LD A,0X24
  315. INDEX           EQU $-1
  316. W_IN1F4         XOR %00000010
  317.                 LD (INDEX),A
  318. W_IN1F2         LD (RD_1F),A
  319.                 LD (REG_A),A
  320.                 RET
  321.  
  322. ;ЧТЕНИЕ ПОРТА 0X3F
  323. W_IN3F          IN A,(RW_PORT1)         ;IN A,(0X3F)
  324.                 LD (REG_A),A
  325.                 RET
  326.        
  327. ;ЧТЕНИЕ ПОРТА 0X5F
  328. W_IN5F          IN A,(RW_PORT2)         ;IN A,(0X5F)
  329.                 LD (REG_A),A
  330.                 RET
  331.  
  332. ;ЧТЕНИЕ ПОРТА 0X7F
  333. W_IN7F          IN A,(RW_PORT3)         ;IN A,(0X7F)
  334.                 LD (REG_A),A
  335.                 RET
  336.  
  337. ;ЧТЕНИЕ ПОРТА 0XFF
  338. W_INFF          LD A,(RD_FF)
  339.                 LD (REG_A),A
  340.                 RET
  341.  
  342. ;ЧТЕННИЕ В "H" ИЗ (С)
  343. W_INHC          LD A,(REG_C)
  344. ;ОПРЕДЕЛЕНИЕ ИЗ КАКОГО ПОРТА ЧТЕНИЕ
  345. W_INHC1         CP 0X1F
  346.                 JR NZ,W_INHC2
  347.                 LD A,(RD_1F)
  348.                 LD (REG_H),A
  349.                 RET
  350.  
  351. W_INHC2         CP 0X3F
  352.                 JR NZ,W_INHC3
  353.                 IN A,(RW_PORT1)         ;IN A,(0X3F)
  354.                 LD (REG_H),A
  355.                 RET
  356.        
  357. W_INHC3         CP 0X5F
  358.                 JR NZ,W_INHC4
  359.                 IN A,(RW_PORT2)         ;IN A,(0X5F)
  360.                 LD (REG_H),A
  361.                 RET
  362.        
  363. W_INHC4         CP 0X7F
  364.                 JR NZ,W_INHC5
  365.                 IN A,(RW_PORT3)         ;IN A,(0X7F)
  366.                 LD (REG_H),A
  367.                 RET
  368.        
  369. W_INHC5         CP 0XFF
  370.                 JR NZ,W_INHC6
  371.                 LD A,(WR_FF)
  372.                 LD (REG_H),A
  373.                 RET
  374.  
  375. W_INHC6         LD BC,(REG_C)
  376.                 IN A,(C)
  377.                 LD (REG_H),A
  378.                 RET
  379.  
  380. ;ЧТЕНИЕ INI
  381. W_INI           LD A,(RD_1F)
  382.                 LD HL,(REG_L)
  383.                 LD (HL),A
  384.                 INC HL
  385.                 DEC B
  386.                 LD (REG_L),HL
  387.                 RET
  388.  
  389. ;АЛЬТЕРНАТИВНОЕ КОПИРОВАНИЕ СЕКТОРА ДЛЯ РАМДИСКА
  390. SV_LD_RAMDISK   PUSH HL
  391.                 CALL CP_TYPEDRIVE
  392.                 POP HL
  393.                 JP NZ,WR_NUM_TRACK              ;ПРИ НЕ СОВПАДЕНИИ РАБОТА ПРОДОЛЖАЕТСЯ С РЕАЛЬНОЙ ДИСКЕТОЙ
  394.                 POP HL                          ;ИНАЧЕ РАБОТАЕМ С РАМДИСКОМ
  395.                 POP HL
  396.                 POP BC
  397.                 XOR A
  398.                 OR B
  399.                 RET Z
  400.                 DI
  401.                 PUSH IX                         ;СОХРАНИЛИ ДЛЯ ВНУТРЕННЕГО ИСПОЛЬЗОВАНИЯ
  402.                 LD IX,(TRD_5CCE)                ;ЧТЕНИЕ ИЛИ ЗАПИСЬ? 00-ЧТЕНИЕ, FF-ЗАПИСЬ, СОХРАНИЛИ ДЛЯ ДАЛЬНЕЙШЕГО ИСПОЛЬЗОВАНИЯ
  403. SVLDRAM1        PUSH BC
  404.                 PUSH HL
  405.                 LD DE,(TRD_5CF4)
  406.                 CALL COM_04
  407.                 LD A,E
  408.                 CALL COM_03
  409.                 INC A
  410.                 OUT (RW_PORT2),A        ;OUT (0X5F),A
  411.                 LD A,D
  412.                 PUSH HL
  413.                 CALL COM_02
  414.                 POP HL
  415.                 RST 0X30
  416.                 DB WWR_RD_SECT
  417.                 LD A,0X10
  418.                 LD HL,TRD_5CF4
  419.                 INC (HL)                        ;УВЕЛИЧЕНИЕ НОМЕРА СЕКТОРА
  420.                 CP (HL)
  421.                 JR NZ,SVLDRAM2
  422.                 LD (HL),0                       ;ЕСЛИ ВЫХОД ЗА ПРЕДЕЛЫ ТРЕКА, ТО СЕКТОР =0
  423.                 INC HL
  424.                 INC (HL)                        ;И УВЕЛИЧИВАЕМ НОМЕР ТРЕКА
  425. SVLDRAM2        POP HL
  426.                 POP BC
  427.                 INC H                           ;УВЕЛИЧИЛИ АДРЕС КОПИРОВАНИЯ НА 256 БАЙТ
  428.                 DJNZ SVLDRAM1
  429.                 POP IX                          ;ПОПОЛЬЗОВАЛИСЬ И ВОССТАНОВИЛИ
  430.                 EI
  431.                 RET
  432.  
  433. READ_SEC_       LD A,(WR_1F)
  434.                 AND 0X0F0
  435.                 CP 0X80
  436.                 JP C,INFF_BIT6
  437.                 CP 0XC0
  438.                 JR NZ,READ_SEC_1
  439.                 IN A,(RW_PORT1)         ;IN A,(0X3F)
  440.                 LD HL,(REG_L)
  441.                 LD (HL),A
  442.                 INC HL
  443.                 DEC B
  444.                 IN A,(RW_PORT2)         ;IN A,(0X5F)
  445.                 LD (HL),A
  446.                 INC HL
  447.                 DEC B
  448.                 LD (REG_L),HL
  449.                 RET
  450.  
  451. READ_SEC_1      PUSH IX
  452.                 LD IXL,0
  453.                 JR WRITE_SEC_1
  454.  
  455. WRITE_SEC_      PUSH IX
  456.                 LD IXL,0XFF
  457. WRITE_SEC_1     CALL W_WR_RD_SECT
  458.                 LD IX,0X8090
  459.                 LD (REG_F),IX                   ;ЕМУЛЯЦИЯ ФЛАГА УСПЕШНОГО ЧТЕНИЯ/ЗАПИСИ СЕКТОРА
  460.                 POP IX
  461.                 RET
  462.  
  463. ;ЧТЕНИЕ ИЛИ ЗАПИСЬ СЕКТОРА РАМДИСКА
  464. W_WR_RD_SECT    LD A,(WR_FF)
  465.                 AND 3
  466.                 INC A
  467.                 LD B,A
  468.                 IN A,(RW_PORT0)
  469.                 RRCA
  470.                 RRCA
  471.                 RRCA
  472.                 RRCA
  473.                 RRCA
  474.                 DJNZ $-1
  475.                 JP C,WR_RD_SEC_M
  476.                 LD A,PAGE_RAMDISK
  477.                 LD BC,WIN_P1
  478.                 OUT (C),A                       ;СТРАНИЦА ЗАГОЛОВКОВ РАМДИСКА
  479.                 IN A,(RW_PORT1)         ;IN A,(0X3F)    ;ВЗЯЛИ НОМЕР ТРЕКА
  480.                 ADD A,A                         ;СТОРОН 2
  481.                 LD C,A
  482.                 LD A,(WR_FF)
  483.                 AND 0X10                        ;ПРОВЕРКА КАКАЯ СТОРОНА ДИСКА
  484.                 JR NZ,WWRRD1
  485.                 INC C                           ;ДЛЯ СТОРОНЫ 1
  486. WWRRD1          LD B,0X42                       ;АДРЕС НАЧАЛА ИНФЫ О СЕКТОРАХ НА ДОРОЖКЕ
  487.                 IN A,(RW_PORT2)         ;IN A,(0X5F)    ;ВЗЯЛИ НОМЕР СЕКТОРА
  488.                 LD L,A
  489.                 LD H,0
  490. WWRRD3          LD A,(BC)
  491.                 LD D,A                          ;ВЗЯЛИ НОМЕР СЕКТОРА
  492.                 INC B
  493.                 LD A,(BC)
  494.                 LD E,A                          ;ВЗЯЛИ РАЗМЕР СЕКТОРА
  495.                 INC B
  496. ;               LD A,D
  497. ;               AND A
  498. ;               JR Z,WWRRD_ERR
  499.                 LD A,L
  500.                 CP D
  501.                 JR Z,WWRRD2
  502.                 LD A,E
  503.                 ADD A,H
  504.                 LD H,A
  505.                 JR WWRRD3
  506.  
  507. WWRRD2          LD A,E
  508.                 RRCA
  509.                 OUT (RW_PORT3),A        ;OUT (0X7F),A   ;РАЗМЕР НАЙДЕННОГО СЕКТОРА
  510.                 LD L,0
  511.                 LD E,L
  512.                 SRL H
  513.                 RR L                            ;HL=СМЕЩЕНИЕ В БЛОКАХ ДО НАЙДЕННОГО СЕКТОРА
  514.                 LD B,0X40
  515.                 LD A,(BC)
  516.                 LD D,A
  517.                 ADD HL,DE                       ;HL=СМЕЩЕНИЕ ОТ НАЧАЛА СТРАНИЦЫ В БЛОКАХ
  518.                 INC B
  519.                 LD A,(BC)
  520.                 LD C,A                          ;СМЕЩЕНИЕ В СТРАНИЦАХ ОТ НАЧАЛА РАМДИСКА
  521.                 LD A,H
  522.                 CP 0X40
  523.                 JR C,WWRRD5
  524.                 SUB 0X40
  525.                 LD H,A
  526.                 INC C
  527. ;HL=СМЕЩЕНИЕ В СТРАНИЦЕ ДО НАЧАЛА СЕКТОРА
  528. WWRRD5          LD A,C                          ;СМЕЩЕНИЕ ДО НОМЕРА СТРАНИЦЫ, ГДЕ УКАЗАННЫЙ СЕКТОР НАЧИНАЕТСЯ
  529.                 ADD A,PAGE_DATARAMD             ;ПРИБАВИЛИ НОМЕР НАЧАЛА РАМДИСК И +1. В 0 СТРАНИЦЕ РАМДИСКА ОПИСАТЕЛИ СЕКТОРОВ
  530.                 LD IXH,A                        ;СОХРАНИЛИ НОМЕР ВЫЧИСЛЕННОЙ СТРАНИЦЫ
  531.                 LD DE,(REG_L)                   ;DE=АДРЕС КУДА/ОТКУДА КОПИРОВАТЬ
  532.                 LD BC,WIN_P1
  533.                 LD A,0XFA
  534.                 OUT (C),A                       ;ВЕРНУЛИ СТАНДАРТНУЮ 5 СТРАНИЦУ
  535. SP_RAMD9        LD A,D                          ;ПРОВЕРКА ГРАНИЦЫ ОТКУДА/КУДА КОПИРОВАТЬ
  536.                 CP 0X80
  537.                 LD A,IXH                        ;ВЕРНУЛИ НОМЕР СТРАНИЦЫ ОЗУ
  538.                 LD BC,WIN_P1                    ;ЕСЛИ ВЕРХНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  539.                 JR NC,SP_RAMD1
  540.                 LD B,HIGH (WIN_P2)              ;ЕСЛИ НИЖНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ ВО 2 ОКНЕ ПРОЕЦИРОВАНИЯ
  541. SP_RAMD1        OUT (C),A                       ;ВКЛЮЧИЛИ ВЫЧИСЛЕННУЮ СТРАНИЦУ
  542.                 LD B,0X40                       ;СТАРШИЙ БАЙТ АДРЕСА НАЧАЛА ВКЛЮЧЕННОЙ СТРАНИЦЫ
  543.                 JR NC,SP_RAMD2
  544.                 LD B,0X80                       ;СТАРШИЙ БАЙТ АДРЕСА НАЧАЛА ВКЛЮЧЕННОЙ СТРАНИЦЫ
  545. SP_RAMD2        LD A,B
  546.                 ADD A,H
  547.                 LD H,A
  548.                 LD A,IXL
  549.                 AND A
  550.                 JR NZ,IN_ROM1
  551.                 LD A,D
  552.                 INC A
  553.                 JR NZ,IN_ROM1
  554.                 LD A,E
  555.                 AND A
  556.                 JR Z,IN_ROM1
  557. IN_ROM4         NEG
  558.                 LD C,A
  559.                 LD B,0
  560.                 LDIR
  561.                 NEG
  562.                 LD C,A
  563. IN_ROM2         EX DE,HL
  564.                 ADD HL,BC
  565.                 EX DE,HL
  566.                 ADD HL,BC
  567.                 IN A,(RW_PORT3)         ;IN A,(0X7F)
  568.                 JP SP_RAMD8_
  569.  
  570. IN_ROM1         LD A,D
  571.                 CP 0X40
  572.                 JR NC,IN_ROM3
  573.                 IN A,(RW_PORT3)         ;IN A,(0X7F)
  574.                 AND A
  575.                 LD BC,0X80
  576.                 JR Z,IN_ROM2
  577.                 LD BC,0X100
  578.                 JR IN_ROM2
  579.  
  580. IN_ROM3         CP 0X80                         ;ПРОВЕРКА ПЕРЕХОДА ГРАНИЦЫ СТРАНИЦ
  581.                 JP NC,SP_RAMD3                  ;ЕСЛИ ВЫШЕ ТО СРАЗУ КОПИРУЕМ
  582.                 CP 0X7F
  583.                 JP C,SP_RAMD3                   ;ЕСЛИ НИЖЕ ТАК ЖЕ СРАЗУ КОПИРУЕМ
  584.                 LD A,E
  585.                 AND A                           ;ЕСЛИ СЕКТОР ПОЛНОСТЬЮ УКЛАДЫВЕТСЯ ДО ГРАНИЦЫ, ТО СРАЗУ КОПИРУЕМ
  586.                 JR Z,SP_RAMD3                   ;ИНАЧЕ ПРИНУДИТЕЛЬНО КОПИРУЕМ В ДВА ПРИЕМА
  587.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ?
  588.                 AND A
  589.                 LD A,E                          ;МЛАДШИЙ БАЙТ АДРЕС В БЛОКЕ
  590.                 JR Z,SP_RAMD4
  591.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  592. SP_RAMD4        NEG
  593.                 LD C,A                          ;КОПИРУЕМ ОСТАТОК ДО КОНЦА БЛОКА
  594.                 LD B,0
  595.                 LDIR
  596.                 NEG
  597.                 EX AF,AF'                       ;СПРЯТАЛИ СКОЛЬКО ОСТАЛОСЬ КОПИРОВАТЬ ИЗ НАЧАЛА СЛЕДУЮЩЕГО БЛОКА
  598.                 LD A,0XFD
  599.                 LD BC,WIN_P2
  600.                 OUT (C),A                       ;ВЕРНУЛИ НОМЕР СТАНДАРТНОЙ СТРАНИЦЫ ВО 2 ОКНЕ ПРОЕЦИРОВАНИЯ
  601.                 LD B,HIGH (WIN_P1)
  602.                 LD A,IXH
  603.                 OUT (C),A                       ;ВЫЧИСЛЕННУЮ СТРАНИЦУ ВКЛЮЧАЕМ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  604.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  605.                 AND A
  606.                 JR Z,SP_RAMD5
  607.                 LD A,D                          ;ДЛЯ ЗАПИСИ
  608.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  609.                 LD D,A
  610.                 JR SP_RAMD6
  611.  
  612. SP_RAMD5        LD A,H                          ;ДЛЯ ЧТЕНИЯ  
  613.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  614.                 LD H,A
  615. SP_RAMD6        EX AF,AF'
  616.                 LD C,A                          ;СКОЛЬКО ОСТАЛОСЬ СКОПИРОВАТЬ БАЙТ
  617.                 LD B,0
  618.                 LDIR
  619.                 IN A,(RW_PORT3)         ;IN A,(0X7F)
  620.                 JR SP_RAMD8_
  621.  
  622. SP_RAMD3        LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  623.                 AND A
  624.                 JR Z,SP_RAMD7
  625.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  626. SP_RAMD7        IN A,(RW_PORT3)         ;IN A,(0X7F)
  627.                 AND A
  628.                 JR NZ,SP_RAMD8
  629.                 CALL COPYHBLOCK                 ;ДЛЯ СЕКТОРА РАЗМЕРОМ 128 БАЙТ КОПИРУЕМ ПОЛОВИНУ И ВЫХОДИМ
  630.  
  631. ;ПРИНУДИТЕЛЬНЫЙ ВОЗВРАТ СТРАНДАРТНЫХ СТРАНИЦ В ОКНА ПРОЕЦИРОВАНИЯ 1 И 2 (5 И 2 СООТВЕСТВЕННО)
  632. ECOPY_BLOCK     LD A,IXL
  633.                 AND A
  634.                 JR Z,ECOPY_BLOCK1
  635.                 EX DE,HL
  636. ECOPY_BLOCK1    LD (REG_L),DE
  637. RET_PAGE_STD    LD A,0XFA                       ;ОБЩАЯ ТОЧКА ЗАВЕРШЕНИЕ КОПИРОВАНИЯ БЛОКА
  638.                 LD BC,WIN_P1
  639.                 OUT (C),A                       ;ВЕРНУЛИ СТРАНИЦУ 5 В 1 ОКНО ПРОЕЦИРОВАНИЯ
  640.                 LD A,0XFD
  641.                 LD B,HIGH (WIN_P2)
  642.                 OUT (C),A                       ;ВЕРНУЛИ СИРАНИЦУ 2 ВО 2 ОКНО ПРОЕЦИРОВАНИЯ
  643.                 RET
  644.  
  645. SP_RAMD8        CALL COPY_BLOCK                 ;ДЛЯ СЕКТОРА 256 БАЙТ КОПИРУЕМ ВЕСЬ И ВЫХОДИМ
  646. SP_RAMD8_       DEC A
  647.                 JR Z,ECOPY_BLOCK
  648.                 OUT (RW_PORT3),A        ;OUT (0X7F),A
  649.                 LD A,IXL
  650.                 AND A
  651.                 JR Z,SP_RAMD0
  652.                 EX DE,HL
  653. SP_RAMD0        LD A,0X3F
  654.                 AND H
  655.                 LD H,A
  656.                 JP SP_RAMD9
  657.  
  658. ;НА ВХОДЕ: H-АДРЕС ЯЧЕЙКИ
  659. ;          L-ПРОЧИТАННОЕ ЗНАЧЕНИЕ
  660. READCMOS        PUSH BC
  661.                 PEC_ON SHADOW_BF
  662.                 LD BC,CMOSD_SET_ADR
  663.                 OUT (C),H
  664.                 LD B,HIGH (CMOSD_RD_WR)
  665.                 IN L,(C)
  666.                 POP BC
  667.                 PEC_OFF SHADOW_BF
  668.                 LD A,L
  669.                 AND A
  670.                 RET
  671.  
  672. ;НА ВХОДЕ: H-АДРЕС ЯЧЕЙКИ
  673. ;          L-ЧТО ТУДА ЗАПИСАТЬ
  674. WRITECMOS       RST 8
  675.                 DB _CMOS_RW
  676.                 DB _WRITE_CMOS
  677.                 RET
  678.  
  679. CP_TYPEDRIVE    PUSH BC
  680.                 IN A,(RW_PORT0)
  681.                 AND 3
  682.                 LD B,A
  683.                 LD A,(TRD_5CF6)
  684.                 CP B
  685.                 POP BC
  686.                 RET
  687.  
  688. SET_DRIVENAME   LD H,VIRT_REAL_DRIVE
  689.                 CALL READCMOS
  690.                 RRCA
  691.                 RRCA
  692.                 AND 3
  693.                 LD (TRD_5D19),A
  694.                 LD (TRD_5CF6),A
  695.                 OR 0X3C
  696.                 RET
  697.  
  698. FORMAT_RAM      LD A,(TRD_5CF6)
  699.                 LD B,A
  700.                 INC B
  701.                 LD A,8
  702.                 RLCA
  703.                 DJNZ $-1
  704.                 LD B,A
  705.                 IN A,(RW_PORT0)
  706.                 AND B
  707.                 JR NZ,FORMAT_RAM3               ;ЕСЛИ БИТ=1 ФОРМАТ ПРИМОНТИРОВАННОГО ОБРАЗА
  708.                 CALL CP_TYPEDRIVE
  709.                 RET NZ                          ;ВЫХОД ДЛЯ ФОРМАТА РЕЛЬНОГО ДИСКА
  710.                 CALL CREATE_TRDTABL             ;ФОРМАТ РАМДИСКА
  711.                 XOR A
  712.                 RET
  713.  
  714. FORMAT_RAM3     LD HL,TRD_5D25
  715.                 LD DE,TRD_5D26
  716.                 LD BC,0XFF
  717.                 LD (HL),B
  718.                 LDIR
  719.                 LD D,B
  720.                 LD E,B
  721.                 LD B,0X10
  722. FORMAT_RAM1     PUSH BC
  723.                 PUSH DE
  724.                 LD B,1
  725.                 LD HL,TRD_5D25
  726.                 CALL COM_06
  727.                 POP DE
  728.                 POP BC
  729.                 INC E
  730.                 DJNZ FORMAT_RAM1
  731.                 XOR A
  732.                 RET
  733.  
  734. ;ПРОВЕРКА НАЛИЧИЯ МАРКЕРА РАМДИСКА
  735. CMP_RAMDISK     PUSH BC
  736.                 PEC_ON SHADOW_BF
  737.                 LD A,PAGE_RAMDISK
  738.                 LD BC,WIN_P1
  739.                 OUT (C),A
  740.                 LD HL,0X7FFF
  741.                 LD D,(HL)
  742.                 DEC H
  743.                 LD E,(HL)                       ;ВЗЯЛИ БАЙТЫ ДЛЯ ПРОВЕРКИ МАРКЕРА
  744.                 LD A,0XFA
  745.                 OUT (C),A
  746.                 POP BC
  747.                 PEC_OFF SHADOW_BF
  748.                 LD HL,"RD"             
  749.                 SBC HL,DE
  750.                 RET Z                           ;ЕСЛИ МАРКЕР НА МЕСТЕ, ТО РАМДИСКА НЕ СОЗДАЕМ
  751. ;СОЗДАНИЕ ЧИСТОГО РАМДИСКА
  752. CREATE_TRDTABL  LD A,PAGE_RAMDISK               ;НУЖНА СТРАНИЦА НАЧАЛА РАМДИСКА, ГДЕ БУДЕТ ТАБЛИЦА ОПИСАТЕЛЕЙ
  753.                 CALL SET4MBPAGE
  754.                 LD HL,0X4000
  755.                 PUSH HL
  756.                 LD DE,0X4001
  757.                 LD BC,0X3FFF
  758.                 LD (HL),L
  759.                 LDIR                            ;ОЧИСТИЛИ СТРАНИЦУ
  760.                 POP DE                          ;АДРЕС НАЧАЛА
  761.                 LD HL,0                         ;СМЕЩЕНИЕ В БЛОКАХ И СТРАНИЦАХ
  762.                 LD A,0XA0
  763. ELT2            EX AF,AF'
  764.                 LD BC,0X1000                    ;СЧЕТЧИК НОМЕРОВ СЕКТОРОВ И ИХ НОМЕРА
  765.                 LD A,L
  766.                 RRCA
  767.                 RRCA
  768.                 LD (DE),A                       ;СМЕЩЕНИЕ В БЛОКАХ ДОРОЖКИ В СТРАНИЦЕ
  769.                 INC D
  770.                 LD A,H
  771.                 LD (DE),A                       ;СМЕЩЕНИЕ В СТРАНИЦАХ ДО ДОРОЖКИ
  772.                 INC D
  773. ELT1            INC C
  774.                 LD A,C
  775.                 LD (DE),A                       ;НОМЕР СЕКТОРА
  776.                 INC D
  777.                 LD A,2
  778.                 LD (DE),A                       ;РАЗМЕР СЕКТОРА
  779.                 INC D
  780.                 DJNZ ELT1                       ;ВНОСИМ В ТАБЛИЦУ ВСЕ НОМЕРА СЕКТОРОВ С РАЗМЕРАМИ
  781.                 LD D,0X40                       ;ВЕРНУЛИ УКАЗАТЕЛЬ В НАЧАЛО
  782.                 INC E                           ;ДЛЯ СЛЕДУЮЩЕЙ ДОРОЖКИ
  783.                 LD BC,0X40
  784.                 ADD HL,BC                       ;ПЕРЕХОД К СЛЕДУЮЩЕЙ ДОРОЖКЕ
  785.                 EX AF,AF'
  786.                 DEC A
  787.                 JR NZ,ELT2                      ;ПОВТОРЯЕМ ДЛЯ ВСЕХ ДОРОЖЕК
  788.                 LD HL,0X7FFF
  789.                 LD (HL),"R"                     ;ВНОСИМ МАРКЕР РАМДИСКА
  790.                 DEC H
  791.                 LD (HL),"D"
  792.                 LD A,PAGE_DATARAMD
  793.                 CALL SET4MBPAGE
  794.                 LD HL,0X4000
  795.                 LD DE,0X4001
  796.                 LD BC,0X0FFF
  797.                 LD (HL),L
  798.                 LDIR
  799.                 LD HL,DSKINFO
  800.                 LD DE,0X48E1
  801.                 LD BC,DSK_END-DSKINFO
  802.                 LDIR
  803.                 LD A,0XFA
  804. ;ВКЛЮЧЕНИЕ В 1 ОКНО ПРОЕЦИРОВАНИЯ ЗАДАННОЙ СТРАНИЦЫ
  805. SET4MBPAGE      PUSH BC
  806.                 LD B,A
  807.                 PEC_ON SHADOW_BF
  808.                 LD A,B
  809.                 LD BC,WIN_P1
  810.                 OUT (C),A
  811.                 LD B,A
  812.                 PEC_OFF SHADOW_BF
  813.                 LD A,B
  814.                 POP BC
  815.                 RET
  816.  
  817. DOS_NOEMUL      DB P_BAS48|0X80                 ;СТРАНИЦА DOS С ЭМУЛЯЦИЕЙ ТОЛЬКО ДЛЯ 3D13
  818. DOS_EMUL        DB P_ADD_BAS48|0X80             ;СТРАНИЦА DOS С ПОЛНЫМ ПЕРЕХВАТОМ ПОРТОВ
  819.  
  820. READ_BYTE_HL_   PUSH BC
  821.                 PUSH HL
  822.                 LD A,(LOC_2A53_)
  823.                 CP 0X0C
  824.                 LD BC,WIN_A0+0X100
  825.                 LD HL,DOS_NOEMUL
  826.                 CALL NZ,WRPORT_RET
  827.                 LD C,A
  828.                 EX (SP),HL
  829.                 LD A,(HL)
  830.                 EX (SP),HL
  831.                 PUSH AF
  832.                 LD A,C
  833.                 CP 0X0C
  834.                 JR Z,RBHL1
  835.                 LD BC,WIN_A0+0X100
  836.                 LD HL,DOS_EMUL
  837.                 CALL WRPORT_RET
  838. RBHL1           POP AF
  839.                 POP HL
  840.                 POP BC
  841.                 RET
  842.